//
// これは「Cassava Editor Ver.1.6.6」のマクロ「行列設定値を取得.cms」(v1.0)です。
//
// 既存の「Cassava Editor」のマクロ「列幅設定其之一取得.cms」(v1.1)に、
// 下記の機能を付加したものです。
//   ●《行の高さ》を、取得する機能
//   ●《１行目を固定の切り替え》や《１列目を固定の切り替え》を、設定する機能
// data:2010-02-01 author:shirafuji
// modified:2010-02-01 author:asukaze
//
//
// １行目の固定の切り替えや１列目の固定の切り替えを、解除します
UnFix() ;
// コメントを外すと、全ての列を画面内に表示します
// ShowAllColumn() ;
// 条件を満たしていたら、２行目を削除します
if(left([1,2],3) == "列幅：") {
   DeleteRow(2) ;
}
// 条件を満たしていたら、２列目目を削除します
if(left([2,1],3) == "行高：") {
   DeleteCol(2) ;
}
gyokot = MessageBox("１行目(━)を固定しますか？", MB_YESNO ) ;
if(gyokot == IDNO){
	rethen = MessageBox("列の幅を編集しますか？", MB_YESNO ) ;
}
//
retkot = MessageBox("１列目(┃)を固定しますか？", MB_YESNO ) ;
if(retkot == IDNO){
	gyohen = MessageBox("行の高さを編集しますか？", MB_YESNO ) ;
}
// 「１行目を固定する」か「列の幅を編集する」を、選択した場合
// 下記を実行します
if(gyokot == IDYES || rethen == IDYES){
	InsertRow(2) ;
	// 列の幅を、２行目に書き出します
	moveto(1,2) ;
	while(Col <= Right){
		[Col,2] = GetColWidth(Col) ;
		if(Col == 1){
			if(gyokot == IDYES){
				[1,2] = str("列幅：F" + [1,2]) ;
			}else{
				[1,2] = str("列幅：" + [1,2]) ;
			}
		}
		move(1,0) ;
	}
}
// 「１列目を固定する」か「行の高さを編集する」を、選択した場合
// 下記を実行します
if(retkot == IDYES || gyohen == IDYES){
	InsertCol(2) ;
	// 行の高さを、２列目目に書き出します
	moveto(2,1) ;
	while(Row <= Bottom){
		[2,Row] = GetRowHeight(Row) ;
		if(Row == 1){
			if(retkot == IDYES){
				[2,1] = str("行高：F" + [2,1]) ;
			}else{
				[2,1] = str("行高：" + [2,1]) ;
			}
		}
		move(0,1) ;
	}
}