//
// これは「Cassava Editor Ver.1.6.6」のマクロ「行列設定値を反映.cms」(v1.0)です。
//
// 既存の「Cassava Editor」のマクロ「列幅設定其之二反映.cms」(v1.11)に、
// 下記の機能を付加したものです。
//   ●《行の高さ》を、反映する機能
//   ●《１行目を固定の切り替え》や《１列目を固定の切り替え》を、反映する機能
// data:2010-02-01 author:shirafuji
//
//
// １行目の固定の切り替えや１列目の固定の切り替えを、解除します
UnFix() ;
// ■■■■■■■■■■■■■■■■■■■■■■■■■■
// 条件を満たしていたら、列の幅を反映します
if(left([1,2],3) == "列幅：") {
	moveto ( 1 , 2 ) ;
	while ( Col <= Right ){
		str = [ Col , 2 ] ;
		if(Col == 1){
			if(mid([1,2],4,1) == "F"){
				str = mid([1,2],5) ;
			}else{
				str = mid([Col,2],4) ;
			}
		}
		SetColWidth ( Col , str ) ;
		move ( 1 , 0 ) ;
	}
}
// 条件を満たしていたら、行の高さを反映します
if(left([2,1],3) == "行高：") {
	moveto ( 2 , 1 ) ;
	while ( Row <= Bottom ){
		str = [ 2 , Row ] ;
		if(Row == 1){
			if(mid([2,1],4,1) == "F"){
				str = mid([2,1],5) ;
			}else{
				str = mid([2,Row],4) ;
			}
		}
		SetRowHeight ( Row  , str ) ;
		move ( 0 , 1 ) ;
	}
}
// ■■■■■■■■■■■■■■■■■■■■■■■■■■
// 条件を満たしていたら、２列目の列の幅を0にします
if(left([2,1],3) == "行高：") {
	SetColWidth (2,0) ;
}
// 条件を満たしていたら、２行目の行の高さを0にします
if(left([1,2],3) == "列幅：") {
	SetRowHeight(2,0) ;
}
// ■■■■■■■■■■■■■■■■■■■■■■■■■■
// 条件を満たしていたら、１列目を固定します
if(left([2,1],4) == "行高：F") {
	FixFirstCol() ;
}
// 条件を満たしていたら、１行目を固定します
if(left([1,2],4) == "列幅：F") {
	FixFirstRow() ;
}